Interfacing function
eng

PEVTDLY_c

File content

//PEVTDLY_c Scicos Continuous Phase Modulator Event block
//Classical interface function ver1.0 - scilab-3.0
//24 février 2008 - INRIA - Author : A.Layec
function [x,y,typ]=PEVTDLY_c(job,arg1,arg2)
 x=[];
 y=[];
 typ=[]

 select job

  case 'plot' then
    standard_draw(arg1)

  case 'getinputs' then
    [x,y,typ]=standard_inputs(arg1)

  case 'getoutputs' then
    [x,y,typ]=standard_outputs(arg1)

  case 'getorigin' then
    [x,y]=standard_origin(arg1)

  case 'set' then
    x        = arg1
    graphics = arg1.graphics
    model    = arg1.model
    exprs    = graphics.exprs

    while %t do
      [ok,period,init_time,exprs]=getvalue('Scicos Phase Modulator Event block',...
        ['Period';'Init time'],...
          list('vec',1,'vec',1),exprs)

      if ~ok then break, end;

      if ok then
        graphics.exprs = exprs
        model.rpar     = [init_time ; period]
        model.firing   = [init_time]
        x.graphics     = graphics
        x.model        = model
        break
     end
    end

  case 'define' then

    period    = 0.1
    init_time = 0

    model           = scicos_model()
    model.sim       = list('pevtdlyz_c',4)
    model.in        = 1
    model.in2       = 1
    model.intyp     = 1
    model.evtin     = []
    model.evtout    = 1
    model.dstate    = []
    model.rpar      = [init_time;period]
    model.blocktype = 'd'
    model.nzcross   = 1
    model.firing    = [init_time]
    model.dep_ut    = [%t %t]

    gr_i=['txt=[''Phase'';''Modulator''];';
                'xstringb(orig(1),orig(2),txt,sz(1),sz(2),''fill'');']

    exprs = [sci2exp(period);sci2exp(init_time)]
    x     = standard_define([2 2],model,exprs,gr_i)
 end
endfunction