Interfacing function
eng


FMODULOB_f

File content


//FMODULOB_f Scicos Float Modulob function block
//Classical interface function ver1.0 - scilab-2.7
//19 octobre 2003 - IRCOM GROUP - Author : A.Layec
function [x,y,typ]=FMODULOB_f(job,arg1,arg2)
x=[];y=[];typ=[]
select job
case 'plot' then
  standard_draw(arg1)
case 'getinputs' then
  [x,y,typ]=standard_inputs(arg1)
case 'getoutputs' then
  [x,y,typ]=standard_outputs(arg1)
case 'getorigin' then
  [x,y]=standard_origin(arg1)
case 'set' then
   x=arg1;
   graphics=arg1.graphics;model=arg1.model;
   exprs=graphics.exprs;

   while %t do

      [ok,ampl,exprs]=getvalue('Scicos Float Modulob function block',...
      ['Amplitude'],list('vec',-1),exprs)

      if ~ok then break,end;
      Nu=size(ampl,'*');if Nu==0 then Nu=[],end

      if ok then
          graphics.exprs=exprs
          model.rpar=ampl
          model.in=Nu;model.out=Nu
          x.graphics=graphics;x.model=model
          break;
      end
   end

case 'define' then
  Nu=1
  ampl=1

  model=scicos_model()
  model.sim=list('fmodulob',2)
  model.in=Nu
  model.out=Nu
  model.evtin=[]
  model.evtout=[]
  model.dstate=[]
  model.rpar=ampl
  model.ipar=[]
  model.blocktype='d'
  model.firing=[]
  model.dep_ut=[%t %f]

  gr_i=['thick=xget(''thickness'')'
        'pat=xget(''pattern'')'
        'fnt=xget(''font'')'
        'xarrows(orig(1)+[0.053;0.982]*sz(1),orig(2)+[0.223;0.22]*sz(2),4,-1)'
        'xarrows(orig(1)+[0.511;0.511]*sz(1),orig(2)+[0.031;0.962]*sz(2),4,-1)'
        'xpoly(orig(1)+[0.078;0.158;0.158;0.511;0.511;0.844;0.844;0.927]*sz(1),orig(2)+[0.692;0.805;0.223;0.814;0.223;0.799;0.223;0.355]*sz(2),"'lines"')'
        'txt=''FMODULOB'';'
        'style=5;'
        'rectstr=stringbox(txt,orig(1),orig(2),0,style,1);'
        'w=(rectstr(1,3)-rectstr(1,2))*%zoom;'
        'h=(rectstr(2,2)-rectstr(2,4))*%zoom;'
        'xstringb(orig(1)+sz(1)/2-w/2,orig(2)-h-4,txt,w,h,''fill'');'
        'e=gce();'
        'e.font_style=style;'
        'xset(''thickness'',thick)'
        'xset(''pattern'',pat)'
        'xset(''font'',fnt(1),fnt(2))']
  exprs=string(ampl)
  x=standard_define([2 2],model,exprs,gr_i)
end
endfunction