Interfacing function
eng

IMODULO_f

File content

//IMODULO_f Scicos Integer Modulo function block
//Classical interface function ver1.0 - scilab-2.7
//19 octobre 2003 - IRCOM GROUP - Author : A.Layec
function [x,y,typ]=IMODULO_f(job,arg1,arg2)
x=[];y=[];typ=[]
select job
case 'plot' then
  standard_draw(arg1)
case 'getinputs' then
  [x,y,typ]=standard_inputs(arg1)
case 'getoutputs' then
  [x,y,typ]=standard_outputs(arg1)
case 'getorigin' then
  [x,y]=standard_origin(arg1)
case 'set' then
   x=arg1;
   graphics=arg1.graphics;model=arg1.model;
   exprs=graphics.exprs;

   while %t do

      [ok,nbit,exprs]=getvalue('Scicos Integer Modulo function block',...
      ['Number of bit'],list('vec',-1),exprs)

      if ~ok then break,end;
      Nu=size(nbit,'*');if Nu==0 then Nu=[],end

      if ok then
          graphics.exprs=exprs
          nbit=int(nbit)
          model.ipar=nbit
          model.in=Nu;model.out=Nu
          x.graphics=graphics;x.model=model
          break;
      end
   end

case 'define' then
  Nu=1
  nbit=4

  model=scicos_model()
  model.sim=list('imodulo',2)
  model.in=Nu
  model.out=Nu
  model.evtin=[]
  model.evtout=[]
  model.dstate=[]
  model.rpar=[]
  model.ipar=nbit
  model.blocktype='d'
  model.firing=[]
  model.dep_ut=[%t %f]

  gr_i=['thick=xget(''thickness'')'
        'pat=xget(''pattern'')'
        'fnt=xget(''font'')'
        'xarrows(orig(1)+[0.498;0.498]*sz(1),orig(2)+[0.022;0.94]*sz(2),4,-1)'
        'xarrows(orig(1)+[0.042;0.973]*sz(1),orig(2)+[0.516;0.516]*sz(2),4,-1)'
        'xpoly(orig(1)+[0.102;0.216;0.216;0.753;0.753;0.878]*sz(1),orig(2)+[0.679;0.874;0.116;0.877;0.113;0.27]*sz(2),"'lines"')'
        'txt=''IMODULO'';'
        'style=5;'
        'rectstr=stringbox(txt,orig(1),orig(2),0,style,1);'
        'w=(rectstr(1,3)-rectstr(1,2))*%zoom;'
        'h=(rectstr(2,2)-rectstr(2,4))*%zoom;'
        'xstringb(orig(1)+sz(1)/2-w/2,orig(2)-h-4,txt,w,h,''fill'');'
        'e=gce();'
        'e.font_style=style;'
        'xset(''thickness'',thick)'
        'xset(''pattern'',pat)'
        'xset(''font'',fnt(1),fnt(2))']
  exprs=string(nbit)
  x=standard_define([2 2],model,exprs,gr_i)
end
endfunction