Interfacing function
eng

INSERZEROVEC_f

File content

//INSERZEROVEC_f Scicos zero pad block
//Classical interface function ver1.0 - scilab-2.7
//22 d?cembre 2003 - IRCOM GROUP - Author : A.Layec
function [x,y,typ]=INSERZEROVEC_f(job,arg1,arg2)
x=[];y=[];typ=[]
select job
case 'plot' then
  standard_draw(arg1)
case 'getinputs' then
  [x,y,typ]=standard_inputs(arg1)
case 'getoutputs' then
  [x,y,typ]=standard_outputs(arg1)
case 'getorigin' then
  [x,y]=standard_origin(arg1)
case 'set' then
   x=arg1;
   graphics=arg1.graphics;model=arg1.model;
   exprs=graphics.exprs;
   while %t do
      [ok,nu,ny,herit,exprs]=getvalue('Scicos zero pad block',...
      ['Size of inputs';...
       'Size of outputs';'Inherit (no:0, yes:1)'],...
      list('vec',1,'vec',1,'vec',1),exprs)

      if ~ok then break,end;

      if ok then
          if herit==1 then
            model.dep_ut=[%t %f]
            [model,graphics,ok]=check_io(model,graphics,[nu],[ny],[],[])
          else
            model.dep_ut=[%t %f]
            [model,graphics,ok]=check_io(model,graphics,[nu],[ny],1,[])
          end
          graphics.exprs=exprs
          model.in=nu;
          model.out=ny
          x.graphics=graphics;x.model=model
          break;
      end
   end

case 'define' then
  nu=256
  ny=512
  herit=1;
  
  model=scicos_model()
  model.sim=list('inserzerovec',4)
  model.in=nu
  model.out=ny
  model.evtin=[]
  model.evtout=[]
  model.dstate=[]
  model.rpar=[]
  model.ipar=[]
  model.blocktype='d'
  model.firing=[]
  model.dep_ut=[%t %f]

  gr_i=['txt=[''Zero'';''pading''];';
    'xstringb(orig(1),orig(2),txt,sz(1),sz(2),''fill'');']
  exprs=[string(nu),string(ny),string(herit)]
  x=standard_define([2 2],model,exprs,gr_i)
end
endfunction