Fonction d'interfaçage
fr

EULERINTEGRAL_m titre

Contenu du fichier

//EULERINTEGRAL_m Scicos vector intgerator by Euler method
//Classical interface function ver1.0 - scicoslab 4.3
//30 mai 2009 - INRIA - Author : A.Layec
function [x,y,typ]=EULERINTEGRAL_m(job,arg1,arg2)
x=[];y=[];typ=[];
select job
case 'plot' then
  standard_draw(arg1)
case 'getinputs' then
  [x,y,typ]=standard_inputs(arg1)
case 'getoutputs' then
  [x,y,typ]=standard_outputs(arg1)
case 'getorigin' then
  [x,y]=standard_origin(arg1)
case 'set' then
  x=arg1
  graphics=arg1.graphics;
  exprs=graphics.exprs
  model=arg1.model;
  while %t do
   text=['Set discrete integral parameters';'(Backward Euler)']
   [ok,step,x0,exprs]=getvalue(text,..
      ['Step';'Initial state'],list('vec',1,'mat',[-1 -2]),exprs)

    if ~ok then break,end

    nu=size(x0,1);
    mu=size(x0,2);
    if (type(x0)==1) then
      if isreal(x0) then
        ut=1;
      else
        ut=2;
      end
    elseif (typeof(x0)=="int32") then 
      ut=3;
    elseif (typeof(x0)=="int16") then
      ut=4;
    elseif (typeof(x0)=="int8") then
      ut=5;
    elseif (typeof(x0)=="uint32") then
      ut=6;
    elseif (typeof(x0)=="uint16") then
      ut=7;
    elseif (typeof(x0)=="uint8") then
      ut=8;
    else
      message ("Bad type for discrete state.");
      ok=%f;
    end

    if ok then
      [model,graphics,ok]=set_io(model,graphics,list([nu mu],ut),list([nu mu],ut),1,[])
      if ok then
        model.rpar     = step
        model.odstate  = list(x0);
        graphics.exprs = exprs;
        x.graphics     = graphics;
        x.model        = model
        break
      end
    end
  end

case 'define' then
  x0   = 0
  step = 1
  nu   = 1
  mu   = 1

  model           = scicos_model()
  model.sim       = list('int_euler_m',4)
  model.in        = nu
  model.in2       = mu
  model.intyp     = 1
  model.out       = nu
  model.out2      = mu
  model.outtyp    = 1
  model.evtin     = 1
  model.rpar      = step
  model.odstate   = list(x0)
  model.blocktype = 'd'

  exprs=[string(step);strcat(sci2exp(x0))]
  gr_i=['thick=xget(''thickness'')'
        'pat=xget(''pattern'')'
        'fnt=xget(''font'')'
        'xpoly(orig(1)+[0.7;0.62;0.549;0.44;0.364;0.291]*sz(1),orig(2)+[0.947;0.947;0.884;0.321;0.255;0.255]*sz(2),"'lines"')'
        'xset(''font'',5,1)'
        'txt=''Euler'';'
        'style=5;'
        'rectstr=stringbox(txt,orig(1),orig(2),0,style,1);'
        'w=(rectstr(1,3)-rectstr(1,2))*%zoom;'
        'h=(rectstr(2,2)-rectstr(2,4))*%zoom;'
        'xstringb(orig(1)+sz(1)/2-w/2,orig(2)-h-4,txt,w,h,''fill'');'
        'e=gce();'
        'e.font_style=style;'
        'xset(''thickness'',thick)'
        'xset(''pattern'',pat)'
        'xset(''font'',fnt(1),fnt(2))'
       ]
  x=standard_define([2 2],model,exprs,gr_i)
end
endfunction